[PATCH 06/11] Fix some autoheader warnings

[Ruben Kerkhof]

AC_DEFINE and AC_DEFINE_UNQUOTED without a description have been deprecated for a while.

$ autoreconf -v
autoreconf: Entering directory `.'
autoreconf: configure.ac: not using Gettext
autoreconf: configure.ac: not using aclocal
autoreconf: configure.ac: tracing
autoreconf: configure.ac: not using Libtool
autoreconf: running: /usr/bin/autoconf
autoreconf: running: /usr/bin/autoheader
autoheader: warning: missing template: CPU_BIG_ENDIAN
autoheader: Use AC_DEFINE([CPU_BIG_ENDIAN], [], [Description])
autoheader: warning: missing template: CPU_LITTLE_ENDIAN
autoheader: warning: missing template: CPU_STRUCT_ALIGN
autoheader: warning: missing template: DEBUGGING
autoheader: warning: missing template: HAVE_ALLOCA_H
autoheader: warning: missing template: HAVE_RL_CRLF
autoheader: warning: missing template: HAVE_RL_DING
autoheader: warning: missing template: HAVE_STRUCT_IP_MREQN
autoheader: warning: missing template: HAVE_SYSLOG
autoheader: warning: missing template: SYSCONF_INCLUDE
autoheader: warning: missing template: TIME_T_IS_64BIT
autoheader: warning: missing template: TIME_T_IS_SIGNED
autoheader: warning: missing template: USE_PTHREADS
autoreconf: /usr/bin/autoheader failed with exit status: 1
---
 aclocal.m4   |  8 ++++----
 configure.ac | 21 ++++++++++++---------
 2 files changed, 16 insertions(+), 13 deletions(-)

diff --git a/aclocal.m4 b/aclocal.m4
index 02c0f76b..6f5560f0 100644
--- a/aclocal.m4
+++ b/aclocal.m4
@@ -87,7 +87,7 @@ AC_MSG_RESULT([test program failed])
 AC_MSG_ERROR([Cannot determine structure alignment])
 ],[bird_cv_c_struct_align=16])
 ])
-AC_DEFINE_UNQUOTED(CPU_STRUCT_ALIGN, $bird_cv_c_struct_align)
+AC_DEFINE_UNQUOTED([CPU_STRUCT_ALIGN], [$bird_cv_c_struct_align], [Usual alignment of structures])
 ])
 
 AC_DEFUN(BIRD_CHECK_TIME_T,
@@ -113,11 +113,11 @@ int main(void)
 ],[bird_cv_type_time_t="32-bit signed"])
 ])
 case "$bird_cv_type_time_t" in
-	*64-bit*)	AC_DEFINE(TIME_T_IS_64BIT) ;;
+	*64-bit*)	AC_DEFINE([TIME_T_IS_64BIT], [1], [Define to 1 if time_t is 64 bit]) ;;
 	esac
 case "$bird_cv_type_time_t" in
 	*unsigned*)	;;
-	*)		AC_DEFINE(TIME_T_IS_SIGNED) ;;
+	*)		AC_DEFINE([TIME_T_IS_SIGNED], [1], [Define to 1 if time_t is signed]) ;;
 	esac
 ])
 
@@ -129,7 +129,7 @@ AC_TRY_COMPILE([#include <netinet/in.h>
 ],[bird_cv_struct_ip_mreqn=no
 ])])
 if test "$bird_cv_struct_ip_mreqn" = yes ; then
-	AC_DEFINE(HAVE_STRUCT_IP_MREQN)
+	AC_DEFINE([HAVE_STRUCT_IP_MREQN], [1], [Define to 1 if you have struct ip_mreqn])
 fi
 ])
 
diff --git a/configure.ac b/configure.ac
index 75e90629..26c37a7b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -96,7 +96,7 @@ if test "$enable_pthreads" != no ; then
 	BIRD_CHECK_PTHREADS
 
 	if test "$bird_cv_lib_pthreads" = yes ; then
-		AC_DEFINE(USE_PTHREADS)
+		AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 		CFLAGS="$CFLAGS -pthread"
 		LDFLAGS="$LDFLAGS -pthread"
 		proto_bfd=bfd
@@ -191,7 +191,7 @@ if ! test -f $sysdesc ; then
 	AC_MSG_ERROR([The system configuration file is missing.])
 fi
 sysname=`echo $sysdesc | sed 's/\.h$//'`
-AC_DEFINE_UNQUOTED(SYSCONF_INCLUDE, "$sysdesc")
+AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [sysdep header to include])
 
 AC_MSG_CHECKING([system-dependent directories])
 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '` lib"
@@ -239,8 +239,8 @@ case $sysdesc in
 		;;
 esac
 
-AC_CHECK_HEADER(syslog.h, [AC_DEFINE(HAVE_SYSLOG)])
-AC_CHECK_HEADER(alloca.h, [AC_DEFINE(HAVE_ALLOCA_H)])
+AC_CHECK_HEADER(syslog.h, [AC_DEFINE([HAVE_SYSLOG], [1], [Define to 1 if you have the <syslog.h> header file])])
+AC_CHECK_HEADER(alloca.h, [AC_DEFINE([HAVE_ALLOCA_H], [1], [Define to 1 if you have the <alloca.h> header file])])
 AC_MSG_CHECKING(whether 'struct sockaddr' has sa_len)
 AC_COMPILE_IFELSE([
   AC_LANG_PROGRAM(
@@ -260,8 +260,11 @@ AC_COMPILE_IFELSE([
   [AC_MSG_RESULT(no)]
 )
 
-AC_C_BIGENDIAN([AC_DEFINE(CPU_BIG_ENDIAN)], [AC_DEFINE(CPU_LITTLE_ENDIAN)],
-		 [AC_MSG_ERROR([Cannot determine CPU endianity.])])
+AC_C_BIGENDIAN(
+  [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
+  [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
+  [AC_MSG_ERROR([Cannot determine CPU endianity.])]
+)
 
 BIRD_CHECK_INTEGERS
 BIRD_CHECK_STRUCT_ALIGN
@@ -269,7 +272,7 @@ BIRD_CHECK_TIME_T
 BIRD_CHECK_STRUCT_IP_MREQN
 
 if test "$enable_debug" = yes ; then
-	AC_DEFINE(DEBUGGING)
+	AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 	if test "$enable_memcheck" = yes ; then
 		AC_CHECK_LIB(dmalloc, dmalloc_debug)
 		if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
@@ -291,8 +294,8 @@ if test "$enable_client" = yes ; then
 						AC_MSG_ERROR([[The client requires ncurses library. Either install the library or use --disable-client to compile without the client.]]))))))
 	AC_CHECK_LIB(readline, rl_callback_read_char, CLIENT_LIBS="-lreadline $CLIENT_LIBS $USE_TERMCAP_LIB",
 		AC_MSG_ERROR([[The client requires GNU readline library 2.1 or newer. Either install the library or use --disable-client to compile without the client.]]), $USE_TERMCAP_LIB)
-	AC_CHECK_LIB(readline, rl_crlf, AC_DEFINE(HAVE_RL_CRLF),,$USE_TERMCAP_LIB)
-	AC_CHECK_LIB(readline, rl_ding, AC_DEFINE(HAVE_RL_DING),,$USE_TERMCAP_LIB)
+	AC_CHECK_LIB(readline, rl_crlf, AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()]),,$USE_TERMCAP_LIB)
+	AC_CHECK_LIB(readline, rl_ding, AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()]),,$USE_TERMCAP_LIB)
 fi
 AC_SUBST(CLIENT)
 AC_SUBST(CLIENT_LIBS)
-- 
2.12.0